4-Digit 7-Segment Display

Here we're going to document the HS5461AS 4 x 7-Segment display.

It is a 5.4" 7-segment display ("54"). "61" indicates the display type - there are many different types, like 41/42, 51/52, 55/56, 61/62, etc - google for more. "B" is common anode ("A" is common cathode). "S" I think is with the dots. "H" is with two dots, for hourly display.

The hardware looks like this:

Wiring

There are a lot of pins involved here, 12 in total.

7 Segment Display	Description	Arduino (Digital)
1	Segment E	7
2	Segment D	8
3	Decimal point	9
4	Segment C	10
5	Segment G	11
6	Digit 4	12
7	Segment B	13
8	Digit 3	2
9	Digit 2	3
10	Segment F	4
11	Segment A	5
12	Digit 1	6

Our Demo Program

The complete code reads as follows:

/*
 * Use the `SevSeg` library to display an increasing number on
 * our four-digit-display.
 */

#include "SevSeg.h"
SevSeg sevseg; //Instantiate a seven segment controller object

void setup()
{
   byte numDigits = 4;

   //
   // In the table above see how these refer to digits.
   //
   byte digitPins[] = {6,3,2,12};

   //
   // In the table above see how these refer to the segments,
   // in alphabetical order :)
   //
   byte segmentPins[] = {5,13,10,8,7,4,11,9};

   bool resistorsOnSegments = false;
   byte hardwareConfig = COMMON_CATHODE;

   sevseg.begin(hardwareConfig, numDigits, digitPins, segmentPins, resistorsOnSegments);
   sevseg.setBrightness(30);
}


//
// The number we're displaying
//
int num=0;

void loop()
{
  //
  // How many times has this display-loop been called?
  //
  static int loop = 0;

  //
  // Bump our loop-index, increase if called enough
  //
  loop++;
  if ( loop > 1000  ) {
    num++;
    loop = 0;
   }

  // Handle over-flow
  if ( num > 9999 )
       num = 0;

  //
  // Set the number.
  //
  sevseg.setNumber(num,0);

  //
  // Refresh the display
  //
  // NOTE: This only updates "some" segments each time it
  // is called, so you have to call it a lot - otherwise you
  // see gibberish.
  //
  // This is why we have the loop index.
  //
  sevseg.refreshDisplay();
}

Download the code.