Message display & acknowledgement

The goal of this project is simple:

• Read a message from the serial console, and display it upon the LCD.
  • Because we allow long-inputs, we'll implement character scrolling.
  • To allow arbitrarily long messages we assume user will add '#' to terminate the input.
• Once read the message can be dismissed by pressing a button.
  • Pressing the button will clear the display.

This project requires only minimal skill, if you've worked through the projects included in the official starter kit, this is because we're just taking the wiring from two of the sample projects, and combining them:

• Wire the LCD display to the arduino, as per project 11 in your starter-guide.
• Wire a button to a spare input-pin, as per project 2 in your starter-guide.
  • In the sample code listed below this is pin 7.

The end result will look something like this:

Code

The code is pretty simple, if you've already completed the starter-project you know how to display text upon the screen. We're just updating that example to read from the serial console, when data becomes available, and clear things when the button is pressed.

/*
   This program reads strings from the serial console, and displays them on the LCD.

   The message received will be scrolled unless/until the button is pressed to clear the display.

   At that point only the display of a new messages will reset
   the output.

*/

// include the library code:
#include <LiquidCrystal.h>

// initialize the library with the numbers of the interface pins
LiquidCrystal lcd(12, 11, 5, 4, 3, 2);

// The clear-button
#define CLEAR 7

// The two lines of text.
char one[128];
char two[128];

// The input-buffer for text from the serial-console
char input[128];
byte index = 0;

// The scroll-offset for the first line of text.
int offset = 0;

void setup() {
  // set up the number of columns and rows on the LCD
  lcd.begin(16, 2);

  // The button we read for clearing the display.
  pinMode(CLEAR, INPUT);

  Serial.begin(9600);
  Serial.write("Power On");

  strcpy( one, "This is the default message." );
  strcpy( two, "by Steve" );

}

void loop() {

  // If we're clearing
  if ( digitalRead(CLEAR) == LOW ) {
    // Turn off the display
    lcd.noDisplay();

    // empty our display-buffer
    memset( one, '\0', sizeof(one));
    return;
  }


  // If we have serial input available ..
  while (Serial.available() > 0)
  {
    // And we've not yet filled our input buffer.
    if (index < sizeof(input))
    {
      // Read & store the next character
      input[index] = Serial.read();
      index++;
      input[index] = '\0';
    }
  }

  //
  // If we have a string with "#" as the last character we can update our message
  //
  if ( strstr( input, "#" ) > 0 )
  {
    Serial.print( "Read from serial : '");
    Serial.print( input );
    Serial.print( "'\n" );

    // Copy this text to the first-line.
    strcpy( one, input);

    // Replace the "#" with a null-terminator
    one[strlen(one) - 1] = '\0';

    // Replace any non-printable characters with a space.
    for( int i = 0 ; i < strlen( one ); i++ )
       if ( !isprint( one[i] ) )
           one[i] = ' ';

    // Add spaces to the end, so it scrolls off the display neatly.
    for ( int i = 0; i < 16; i++ )
      strcat( one, " " );

    //
    // Empty our input buffer, and reset our stcroll-state.
    //
    memset( input, '\0', sizeof(input) );
    index = 0;
    offset = 0;
  }

  // If our text is empty - then do nothing
  if ( strlen(one) < 1 )
    return;

  // Otherwise restore the display
  lcd.display();

  // Move to the top-left.
  lcd.setCursor(0, 0);

  // Draw 16 characters from the start of the first string.
  for ( int i = 0; i < 16; i++ )
  {
    int c = i + offset;
    if ( c < strlen( one ) )
      lcd.write(one[c]);
  }

  // Show the second inline.
  lcd.setCursor(0, 1);
  lcd.print( two );

  // Handle scrolling the first line
  offset += 1;
  if ( (offset + 16) > strlen(one) )
    offset = 0;

  delay(500);
}

Download the code.

Usage

Once you've loaded the code in your IDE, compiled & uploaded it, your display should show:

This is the default message.
by Steve

You can open the serial interface in your IDE and type in a new message:

I like cakes, I also like puppies and kittens!#

NOTE: The "#" character will signify the end of the message, and will not be displayed.

The new message will cheerfully scroll across the first line of the display, and will continue to do so until you press the button you've wired up. Think of the button as an "acknowledge & clear" thing.

ProTip: If your board is connected to a Linux system you can update the message from your shell.

In my case I can run this to update the message:

$ echo "I am awake#" > /dev/ttyACM2

Challenges?

• At the moment the first line always scrolls.
  • Can you make it only scroll if the input is longer than the 16 characters that will fit on it?
• The second line just contains the string "by Steve".
  • Can you split the message across two lines, with no scrolling, if the message is less than 32 characters?

If you're using a D1-mini, or some other board which has built in networking, can you make the message come from a remote HTTP server?